Computer Generated Art - Student Gallery Display

Assignment Six by fuzzyshark

//you must listen to the tron soundtrack while
//looking at this picture for the full effect =)

startshape tron

background{b -1}

size{s 365 275 x -180 y -25}

rule tron{
	15*{x 25}grid{z 100}
	15*{x 25}grid_2{z 100}
	circle_floor{s 10 x 180 y -190 z -1000 a -.5}
	gradient_2{s 10 x 180 y -250 z -10000000000 a -.9}
	light_cycle{x 300 y -75 z 4100 s 25}
	light_cycle_path_blue{s 300 27 x 135 y -72 z 4100}
	light_cycle_orange{x 260 y -60 z 4000 s 25}
	light_cycle_path_orange{s 300 27 x 95 y -57 z 4000}
	border{s 1 1.15 y -2}
	SQUARE{z 6000  s 50 1000 x -4 h 238 b .11 sat .68 }
	SQUARE{z 6000  s 70 1000 x 374 h 238 b .11 sat .68 }
	SQUARE{z 6000 r 90  s 50 1000 y 171 h 238 b .11 sat .68 }
	SQUARE{z 6000 r 90  s 50 1000 y -117 h 238 b .11 sat .68 }
//	sky{x 180 y 95 z -100000 s 50}
}

rule grid{
	20*{y 2}{10*{x 2}base{}}
}

rule grid_2{
	20*{y 2}{10*{x 2}base{}}
}

//------------------------------RANDOMIZING THE WINDOWS
rule base{
	SQUARE{h 185 sat .63 b .82}
}

rule base{
	SQUARE{h 182 sat .95 b .45}
}

rule base{
	SQUARE{b 1}
}

rule base{
}

rule base{
	base{x 1}
}

rule base{
	base{x -1}
}

rule base{
	base{y 1}
}

rule base{
	base{y -1}
}

rule base .1{
	grid{s .2}
}

//------------------------------RANDOMIZING THE BUILDINGS
rule grid{
	grid{x 3}
}

rule grid{
	grid{y 3}
}

rule grid{
	grid{s .9 1}
}

rule grid{
	grid{s 1 1.15}
}

//------------------------------RANDOMIZING GRID_2
rule grid_2{
	grid_2{x 3}
}

rule grid_2{
	grid_2{y 3}
}

rule grid_2{
	grid_2{s .9 1}
}

rule grid_2{
	grid_2{s 1 1.15}
}

//------------------------------GROUND
startshape circle_floor

rule circle_floor{
	15*{y 2.5 s .9}circles{}
	15*{y 2.5 s .9}circles{x -70}
}

rule circles{
	28*{x 2.5}CIRCLE{h 186 sat .15 b 97}
}

//------------------------------CLOUDS
rule sky{
	cloud{s 1 .3}
}

rule cloud{
	cloud_shape{a -1}
}

rule cloud_shape{
	CIRCLE{}
	horizontal{}
	vertical{}
}

rule horizontal{
	cloud_shape{x 1 s .92 a .001 sat .68 h 194}
}

rule horizontal{
	cloud_shape{x -1 s .92 a .001 b .03}
}

rule vertical{
	cloud_shape{y 1 s .7 a .001 b .03}
}

rule vertical{
	cloud_shape{y -1 s .7 a .001 sat .68 h 194}
}

//------------------------------GRADIENT
rule gradient_2{
	gradient{|h 194 h 238 b .11 sat .68 s 100 1}
}

rule gradient{
	1000*{y .1 h -.002|}SQUARE{}
}

//------------------------------BLUE LIGHT CYCLE
rule light_cycle{
	wheel{x .75 z 2}
	wheel{x -.75 z 2}
	body{r 180 s .01 .008}
	body{r 180 s .009 .007 h 185 sat .63 b .82}
	body{r 180 s .0085 .0065}
}

rule wheel{
	CIRCLE{}
	CIRCLE{s .85 z 1 h 185 sat .63 b .82}
	CIRCLE{z 2 s .8}
}

rule body{
	360*{r -.5}{100*{x 1}SQUARE{}}
}

//------------------------------ORANGE LIGHT CYCLE
rule light_cycle_orange{
	wheel_orange{x .75 z 1}
	wheel_orange{x -.75 z 1}
	body_orange{r 180 s .01 .008}
	body_orange{r 180 s .009 .007 h 40 sat 0.81 b 1}
	body_orange{r 180 s .0085 .0065}
}

rule wheel_orange{
	CIRCLE{}
	CIRCLE{s .85 z 1 h 40 sat 0.81 b 1}
	CIRCLE{z 2 s .8}
}

rule body_orange{
	360*{r -.5}{100*{x 1}SQUARE{}}
}

//------------------------------BLUE PATH
rule light_cycle_path_blue{
	SQUARE{h 185 sat .63 b .82 a -.5}
	SQUARE{s 1 .1 y .5 h 185 sat .63 b .82}
	SQUARE{s 1 .1 y -.5 h 185 sat .63 b .82}
}

//------------------------------ORANGE PATH
rule light_cycle_path_orange{
	SQUARE{h 40 sat 0.81 b 1 a -.5}
	SQUARE{s 1 .1 y .5 h 40 sat 0.81 b 1}
	SQUARE{s 1 .1 y -.5 h 40 sat 0.81 b 1}
}

//------------------------------BORDER
	//--------------------BLUE
rule blue_border{
	SQUARE{s 0.01 1 h 185 b 1 sat 1}
	blue_border_corner{r 30 s 1 0.15 y 0.564 x -0.039}
	blue_border_corner{r -30 s 1 0.15 y -0.564 x -0.039}
}

rule blue_border_corner{
	SQUARE{s .01 1 h 185 b 1 sat 1}
}
	//--------------------ORANGE
rule orange_border{
	SQUARE{s 0.01 1 h 40 b 1 sat 1}
}

rule orange_border_corner{
	SQUARE{s .01 1 h 40 sat 1 b 1}
}
	//--------------------BORDER
rule border{
	orange_border{z 6000 r 90 x 180 y -80 s 320}
	orange_border{z 6000 r 90 x 180 y 130 s 320}
	blue_border{z 6000 s 210 x 20 y 25}
	blue_border{z 6000 s 210 x 340 y 25 f 90}
}